#include <usbh_midi.h>
#include <usbhub.h>
#include <SoftwareSerial.h>

#define VS1053_BANK_DEFAULT 0x00
#define GM_ACOUSTIC_PIANO   0x00
#define VELOCITY_FFF         127
#define MIDI_CHAN_BANK      0x00
#define MIDI_CHAN_VOLUME    0x07
#define MIDI_CHAN_MSG       0xB0
#define MIDI_CHAN_PROGRAM   0xC0
#define VELOCITY_MP           64

USB Usb;
USBHub Hub(&Usb);
USBH_MIDI  Midi(&Usb);

void MIDI_poll();

void onInit() {
	char buf[20];
	uint16_t vid = Midi.idVendor();
	uint16_t pid = Midi.idProduct();
//	sprintf(buf, "VID:%04X, PID:%04X", vid, pid);
//	Serial.println(buf); 
}

void setChannelBank(uint8_t channel, uint8_t bank) {
	Serial.write(MIDI_CHAN_MSG | channel);
	Serial.write((uint8_t)MIDI_CHAN_BANK);
	Serial.write(bank);
}

void setChannelVolume(uint8_t channel, uint8_t vol) {
	Serial.write(MIDI_CHAN_MSG | channel);
	Serial.write(MIDI_CHAN_VOLUME);
	Serial.write(vol);
}

void setInstrument(uint8_t channel, uint8_t instrument) {
	Serial.write(MIDI_CHAN_PROGRAM | channel);
	Serial.write(instrument);
	delay(10);
}

void setup() {

	uint8_t channel =  0;

	Serial.begin(31250);

	if (Usb.Init() == -1) {
		while (1); //halt
	}
	delay( 200 );

	// Register onInit() function
	Midi.attachOnInit(onInit);

	setChannelBank(channel, VS1053_BANK_DEFAULT);
	setChannelVolume(channel, VELOCITY_FFF);
	setInstrument(channel, GM_ACOUSTIC_PIANO);
}

void loop() {
	Usb.Task();
	if ( Midi ) MIDI_poll();
}

// Poll USB MIDI Controler and send to serial MIDI
void MIDI_poll() {
	uint8_t bufMidi[MIDI_EVENT_PACKET_SIZE];
	uint16_t  rcvd;

	if (Midi.RecvData( &rcvd,  bufMidi) == 0 ) {
		switch(bufMidi[0]) {
			case 0x09: // Note-on
				bufMidi[3] = VELOCITY_MP;
				Serial.write(&bufMidi[1],3);
				break;
			case 0x08: // Note-off
			case 0x0B: // Continuous controller
			case 0x0E: // Pitch bend
				Serial.write(&bufMidi[1],3);
				break;
			case 0x0A: // After-touch
			case 0x0C: // Program change
				Serial.write(&bufMidi[1],2);
				break;
			case 0x0D: // Channel Pressure
				break;
			case 0x0F: // System Realtime message (non-musical commands)
				Serial.write(&bufMidi[1],1);
				break;
		}
 	}
}