#include <Wire.h>
#include <HardwareSerial.h>

HardwareSerial SerialBLE(0);
HardwareSerial SerialPRN(1);

#define INTERVAL   (50)
#define PIN_09600  D1
#define PIN_19200  D2
#define PIN_38400  D3

int baudrate;
int max_column = 48;

void set_prn(HardwareSerial *serial)
{
	// 初期化(印字バッファ内データ抹消))
	serial->write(0x1b);
	serial->write(0x40);

	if (baudrate == 19200) {

		max_column = 42;

		// Character font B (9*17)
		serial->write(0x1b);
		serial->write(0x21);
		serial->write(0x01);

		// Set line spacing
		serial->write(0x1b);
		serial->write(0x33);
		serial->write(0x14);
	}

	if ((baudrate == 9600)||(baudrate == 38400)) {

		max_column = 48;

		// ANK文字フォント指定(8x16ドット)
		serial->write(0x1b);
		serial->write(0x68);
		serial->write(0x30);

		// 漢字フォント指定(16x16ドット)
		serial->write(0x12);
		serial->write(0x53);
		serial->write(0x31);

		// 文字コード指定(UTF-8)
		serial->write(0x1b);
		serial->write(0x24);
		serial->write(0x30);
	}

	// 行間スペース量指定(0ドット)
	serial->write(0x1b);
	serial->write(0x41);
	serial->write(0x01);

	// 文字間スペース量指定(0ドット)
	serial->write(0x1b);
	serial->write(0x20);
	serial->write((uint8_t)0x00);
}

void put_prn(HardwareSerial *serialin, HardwareSerial *serialout)
{
	int ch;
	int row = 0;
	int col = 4;
	int numByte;
	int i;

	while(1) {
		while (serialin->available()) {
			if (row == 0) {
				serialin->write(0x0a);
				serialout->write(0x0d);
				serialout->printf("%03d ",++row);
				serialin->printf("%03d ",row);
			}
			ch = serialin->read();
			switch(ch) {
				case 0x09: // TAB
					serialin->write(' ');
					serialout->write(' ');
					++col;
					break;
				case 0x0d:
					--col;
					break;
				case 0x0a:
					// 行末に改行コードがきた場合は、自動改行されるので無視する
					if ( col % max_column ) {
						serialin->write(ch);
						serialout->write(0x0d);
					}
					serialout->printf("%03d ",++row);
					serialin->printf("%03d ",row);
					col = 4;
					break;
				case EOF: // EOF
				case 0x1a:
					serialin->write(0x0a);
					serialin->write(0x0a);
					serialout->write(0x0d);
					serialout->write(0x0d);
					serialout->write(0x0d);
					return;
					break;
				default:
					if ((ch & 0x80) == 0x00) { // 1byte文字
						serialin->write(ch);
						serialout->write(ch);
						++col;
					} else {
						// 48桁目に2バイト文字がきた場合は、改行する
						if ( !((++col) % max_column)) {
							serialout->write(0x0d);
							col = 2;
						} else {
							++col;
						}
						// UTF-8文字コードのバイト数判定
						if ((ch & 0xE0) == 0xC0)        { numByte=2; // 2byte文字
						} else if ((ch & 0xF0) == 0xE0) { numByte=3; // 3byte文字
						} else if ((ch & 0xF8) == 0xF0) { numByte=4; // 4byte文字
						} else if ((ch & 0xFC) == 0xF8) { numByte=5; // 5byte文字
						} else if ((ch & 0xFE) == 0xFC) { numByte=6; // 6byte文字
						} else { numByte=0;
						}
						if ((baudrate == 9600)||(baudrate == 38400)) {
							serialout->write(ch);
						} else {
							serialin->write('?');
							serialout->write('?');
						}
						for(i=1;i<numByte;) {
							if (serialin->available()) {
								ch = serialin->read();
								if ((baudrate == 9600)||(baudrate == 38400)) {
									serialin->write(ch);
									serialout->write(ch);
								}
								i++;
							} else {
								delay(10);
							}
						}
					}
					break;
			}
			if (!(col % max_column)) {
				// AS-289R2は自動改行される
				serialin->write(0x0a);
				if ((baudrate == 9600)||(baudrate == 38400)) serialout->write(0x0a);
			}
		}
	}
}

void setup() 
{
	Wire.begin();

	pinMode(PIN_09600, INPUT_PULLUP);
	pinMode(PIN_19200, INPUT_PULLUP);
	pinMode(PIN_38400, INPUT_PULLUP);

	if (digitalRead(PIN_09600) == LOW) {
		baudrate = 9600;
	} else if (digitalRead(PIN_19200) == LOW) {
		baudrate = 19200;
	} else if (digitalRead(PIN_38400) == LOW) {
		baudrate = 38400;
	} else {
		baudrate = 9600;
	}

	SerialBLE.begin(9600, SERIAL_8N1, RX, TX);
	SerialPRN.begin(baudrate, SERIAL_8N1,  9, 10);

	set_prn(&SerialPRN);
}

void loop()
{
	if (SerialBLE.available()) put_prn(&SerialBLE, &SerialPRN);
}