#define PIN_CE   2
#define PIN_IO   3
#define PIN_SCLK 4

const uint8_t Sun = 1;
const uint8_t Mon = 2;
const uint8_t Tue = 3;
const uint8_t Wed = 4;
const uint8_t Thr = 5;
const uint8_t Fri = 6;
const uint8_t Sat = 7;

static char clockTime[13]; // 時刻文字列 yymmddhhiiss
static char editTime[20];  // 時刻表示用文字列
static char shortTime[7];  // 撮影用文字列

// 整数値をBCDに変換
byte dec2bcd(int x) {
  return ((x/10)<<4)+(x%10);
}

uint8_t bcd2dec(const uint8_t bcd) {
	return (10*((bcd&0xF0)>>4)+(bcd&0x0F));
}

uint8_t shiftInEx() {
	uint8_t input_value=0;
	uint8_t bit=0;
	pinMode(PIN_IO,INPUT);
	for (int i=0; i<8; ++i) {
		digitalWrite(PIN_SCLK,HIGH);
		delayMicroseconds(1);
		digitalWrite(PIN_SCLK,LOW);
		delayMicroseconds(1);

		bit = digitalRead(PIN_IO);
		input_value |= (bit<<i); // Bits are read LSB first.
	}
	return input_value;
}

void shiftOutEx(const uint8_t value) {
	bool pinModeFlag = false;
	pinMode(PIN_IO, OUTPUT);
	for (int i=0;i<8;++i) {
		digitalWrite(PIN_IO, (value>>i)&1);
		delayMicroseconds(1);
		digitalWrite(PIN_SCLK,HIGH);
		delayMicroseconds(1);

		// We're about to read data -- ensure the pin is back in input mode
		// before the clock is lowered
		if (i==7) {
			if (value==0xBF) pinModeFlag=true; // clock Burst Read
			if ((value>=0x80)&&(value<=0x8D)&&(value%2)) pinModeFlag=true;
		}
		if (pinModeFlag) {
			pinMode(PIN_IO,INPUT);
		} else {
			digitalWrite(PIN_SCLK,LOW);
			delayMicroseconds(1);
		}
	}
}

uint8_t readReg(const uint8_t reg) {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(reg);
	uint8_t dec = bcd2dec(shiftInEx());
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
	return dec;
}

void writeReg(const uint8_t reg, uint8_t value) {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(reg);
	shiftOutEx(value);
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
}

// Initialize a new chip by turning off write protection.
// These method needn't always be called.
void writeProtect() {
	writeReg(0x8E,0x00);
}

// トリクルチャージ設定（1ダイオード,2kΩ）
void trickleCharge() {
	writeReg(0x90,0xA5);
}

void getDateBurst() {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(0xBF); //clock Burst Read
	uint8_t ss  = bcd2dec(shiftInEx() & 0x7F);
	uint8_t ii  = bcd2dec(shiftInEx());
	uint8_t hh  = bcd2dec(shiftInEx());
	uint8_t dd  = bcd2dec(shiftInEx());
	uint8_t mm  = bcd2dec(shiftInEx());
	uint8_t day = bcd2dec(shiftInEx());
	uint8_t yy  = bcd2dec(shiftInEx());
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
	sprintf(clockTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	sprintf(editTime, "20%02d-%02d-%02d %02d:%02d:%02d",yy,mm,dd,hh,ii,ss);
	sprintf(shortTime,"%02d%02d%02d",yy,mm,dd);
}

void getDate() {
	uint8_t yy,day,mm,dd,hh,ii,ss,ck;
	while(1) {
		ss  = readReg(0x81);
		ii  = readReg(0x83);
		hh  = readReg(0x85);
		dd  = readReg(0x87);
		mm  = readReg(0x89);
		day = readReg(0x8A);
		yy  = readReg(0x8D);
		ck  = readReg(0x81);
		// 59秒→0秒対策
		if (ck>=ss) break;
	}
	sprintf(clockTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	sprintf(editTime, "20%02d-%02d-%02d %02d:%02d:%02d",yy,mm,dd,hh,ii,ss);
	sprintf(shortTime,"%02d%02d%02d",yy,mm,dd);
}

// 時刻を設定する
void adjustClock() {
	char updateTime[13];
	int yy=20,mm=10,dd=2,hh=8,ii=58,ss=00,day=Fri;
	sprintf(updateTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	getDateBurst();
	// シリアル通信を開始の、Arduinoオートリセット機能対応
	if (strcmp(updateTime,clockTime)>0) {
		writeProtect();
		digitalWrite(PIN_SCLK,LOW);
		digitalWrite(PIN_CE,HIGH);
		delayMicroseconds(4);
		shiftOutEx(0xBE); //clock Burst Write
		shiftOutEx(dec2bcd(ss));
		shiftOutEx(dec2bcd(ii));
		shiftOutEx(dec2bcd(hh));
		shiftOutEx(dec2bcd(dd));
		shiftOutEx(dec2bcd(mm));
		shiftOutEx(dec2bcd(day));
		shiftOutEx(dec2bcd(yy));
		//shiftOutEx(0x00); // Write protecton register
		digitalWrite(PIN_CE, LOW);
		delayMicroseconds(4);

		trickleCharge();
	}
}

void setup() {

	digitalWrite(PIN_CE, LOW);
	pinMode(PIN_CE, OUTPUT);
	pinMode(PIN_IO, INPUT);
	digitalWrite(PIN_SCLK, LOW);
	pinMode(PIN_SCLK,OUTPUT);

	Serial.begin(115200);

	adjustClock();
}

void loop(){
	//getDateBurst();
	getDate();
	Serial.println(editTime);
	delay(1000);
}