MIDI再生：FM音源YMF825+ESP32編
2025.02.08
YouTube 動画でポイントを説明しています。画像をクリックすると再生できます。
FM音源YMF825+micro:bit編
以前掲載した記事では、Raspberry Pi と micro:bit をシリアル接続して、Raspberry Pi側キーボードのキーを押すと、
micro:bit に接続されたヤマハFM音源YMF825ボードから音がでる仕組みを構築しました。
micro:bit では Pythonで書かれたコードを実行していましたが、これをArduino言語に書き換えを行い、ESP32上で実行できるようにして、MIDIコードを流し込むことで演奏できるようにしました。
●ヤマハFM音源LSI YMF825搭載モジュール YMF825Board
ヤマハのFM音源チップYMF825（SD-1）を搭載した音源ボードです。ヤマハ独自のFMシンセサイザを搭載し、数種類のパラメータ指定により豊かなサウンドを再生することが可能です。
ArduinoやRaspberry Pi等のマイコンボードから、SPIを通して直接YMF825のレジスタを制御することで発音させます。スピーカーアンプも搭載しているので、アンプ回路を別途外部に用意する必要がありません。
・4オペレータのFM音源
・最大16音同時に発音可能
・FMの基本波形29種類内蔵、アルゴリズム8種類
・SPIによるシリアルインタフェース
・スピーカアンプ内蔵
・3バンドイコライザ内蔵
・16 bitモノラルD/Aコンバータ内蔵
・動作電圧：5V
YAMAHA YMF825 Board の表と裏です。ピンの脇に刻印があるので、配線は間違えないと思います。
●Adafruit QT Py ESP32-S2 WiFi Dev Board with STEMMA QT
・ESP32-S2 240MHz
・4 MB Flash & 2 MB PSRAM
・2.4 GHz Wi-Fi (SoC)
・Two I2C ports
・Hardware UART
・Hardware SPI
・Hardware I2S on any pins
・3.3V regulator with 600mA peak output
Ref.Adafruit QT Py ESP32-S2
Qt Py ESP32-S2 Pinout
●YAMAHA YMF825 Board と QT Py ESP32-S2の結線 (SPI接続)
| YMF825Board | - | QT Py ESP32-S2 | - | Raspberry Pi |
| SS | - | A2 | | |
| MOSI | - | MO | | |
| MISO | | | | |
| SCK | - | SCK | | |
| GND | - | GND | | |
| 5V | - | 5V | | |
| RST_N | | | | |
| Audio Out | | | | |
| 3.3Vin | | | | |
| | | Serial | - | /dev/ttyACM0 |
※SPI接続はレベル変換を行っていないので、MOSI(3.3V→5V)のみで、MISO(5V→3.3V)は非接続にします
Adafruit Qt Py ESP32-S2 と YMF825ボードをSPI接続しています
Raspberry Pi 上でttymidiを起動して、MIDIファイルを再生、USB接続でMIDIデータをESP32に流し込んでいます。
ラジオのLINE-INに繋いで音を出させます。
ttymidiに関しては下記をご覧ください
ttymidi + SAM2695
●ソースコード
// ヤマハ製YMF825(SD-1)使用FM音源LSIモジュール
// 発売日 2017/09/16 ウダデンシ
// SD-1は4opの16polyのFM音源チップ。SPI通信でレジスタを直接制御する基板。
// 基板には水晶(12.288MHz)を搭載し、チップにはDACとアンプを内蔵し、レジスタを制御するだけで音を出す。
// YMF825内蔵のアンプでスピーカを直接駆動可能
// 3バンドのイコライザを内蔵
// ・ヤマハ公式GitHubアカウントで、制御用サンプルプログラムを随時公開予定
// Arduino UNO & NANO - YMF825 Board 接続
// D9 - RST_N: reset
// D10 - SS: chip select(SPI interface)
// D11 - MOSI: serial data input(SPI interface)
// D12 - MISO: serial data output(SPI interface) ESP32では非接続
// D13 - SCK: serial clock(SPI interface)
// GND - GND: ground
// 5V - 5Vin: power supply(5v)
// Audio: Audio Out (3.5mmヘッドフォン出力)
// 3.3Vin: power supply(3.3v) 3.3Vin端子未使用
//
// Ref. https://github.com/yamaha-webmusic/ymf825board
#include <SPI.h>
#define PIN_CS A2
#define PIN_RST A3
// 音色テーブルは1音色あたり30バイト、最大で480バイトを丸ごと設定します。
// 規定のヘッダとフッタを付与した上で、レジスタ#7に対して頭から順に送ることで内部の音色テーブルにプリセットされます。
// SPIバースト転送が使えますが、レジスタ#7に対して1バイトずつ設定でももちろん構いません。
// ヘッダでは音色テーブルの設定数を0～16で指定します。音色番号ではない点に注意。
// 各音色データは必ず1音色30バイト単位での設定になります。特定のレジスタだけをピンポイントで変更する手段はありません。
// また、音色テーブルの設定時には全てのチャンネルで発音が停止している必要があります。
// AR: アタックレート、立ち上がりの速さ 15で最速、0で立ち上がらない(鳴らない)
// DR: ディケイレート、立ち上がり後の減衰の速さ 15で最速、0で減衰しない
// SL: サステインレベル、ディケイ後の音量 15で消える、0で減衰しない
// SR: サステインレート、ディケイ後の減衰の速さ 15で最速、0で減衰しない
// RR: リリースレート、キーオフ後の減衰の速さ 15で最速、0で減衰しない(鳴り続ける)
// FB: フィードバック、自分自身をモジュレート（オペレータ1と、オペレータ3のアルゴリズム2と5のみ)
unsigned char tone_data[485] = {
// Header: 1byte(80H + Maximum Tone Number)
0x8F, // 80H + Tone Number
// GrandPiano
0x01, 0x43
0x00, 0x67, 0xFF, 0x9D, 0x00, 0x10, 0x40,
0x21, 0x33, 0xE2, 0xA3, 0x00, 0x50, 0x00,
0x10, 0x41, 0xD3, 0x88, 0x01, 0x10, 0x00,
0x21, 0x62, 0xD4, 0x02, 0x01, 0x10, 0x00,
// Bright Piano
0x0, 0x43,
0x20, 0x22, 0xf5, 0x9e, 0x0, 0x10, 0x0,
0x20, 0x32, 0xff, 0x72, 0x0, 0x50, 0x0,
0x20, 0x22, 0xfd, 0x66, 0x1, 0x10, 0x0,
0x10, 0x52, 0xf4, 0x28, 0x1, 0x10, 0x0,
// Electric Piano
0x01,0x45, // modify BO:0 -> BO:1
0x51,0xC4,0xFB,0x8C,0x44,0x70,0x95,
0x10,0x82,0xFF,0x12,0x45,0x10,0x00,
0x11,0xB0,0xF1,0x49,0x44,0x10,0x02,
0x11,0x72,0xFF,0x10,0x41,0x10,0x00,
// Harpsichord
0x0, 0x46,
0x30, 0x52, 0xe0, 0x1, 0x0, 0x10, 0x24,
0x0, 0x52, 0xf3, 0x53, 0x0, 0x60, 0x18,
0x0, 0x13, 0xf6, 0x72, 0x0, 0x70, 0x20,
0x20, 0x72, 0xef, 0x10, 0x3, 0x10, 0x28,
// Wibraphone
0x0, 0x45,
0x20, 0x44, 0xc2, 0x5c, 0x41, 0x74, 0x0,
0x20, 0x59, 0xd6, 0x1e, 0x51, 0x45, 0x0,
0x20, 0x34, 0xc2, 0x78, 0x51, 0x85, 0x0,
0x30, 0x42, 0xdf, 0x1c, 0x31, 0x13, 0x0,
// Rock Organ
0x0, 0x87,
0x10, 0xdf, 0xf0, 0x25, 0x70, 0x17, 0x4,
0x0, 0xaf, 0xb1, 0x15, 0x50, 0x15, 0xa8,
0x0, 0xef, 0xf0, 0x24, 0x13, 0x21, 0x0,
0x0, 0xef, 0xf0, 0x24, 0x33, 0x3, 0x88,
// Church Organ
0x0, 0x47,
0x0, 0x5f, 0x90, 0x4e, 0x0, 0x30, 0x0,
0x0, 0x27, 0xb2, 0x74, 0x0, 0x70, 0x0,
0x0, 0x5f, 0x80, 0x12, 0x0, 0x10, 0x0,
0x0, 0x57, 0x80, 0x12, 0x0, 0x0, 0x28,
// Harmonica
0x0, 0x84,
0x0, 0x9f, 0xf0, 0xb3, 0x7, 0xe0, 0x0,
0x0, 0x8f, 0xf0, 0xa4, 0x11, 0xa1, 0x0,
0x0, 0x8f, 0xf0, 0x90, 0x3, 0x10, 0x0,
0x0, 0x8f, 0x60, 0xe, 0x1, 0x20, 0x0,
// Acoustic Guitar
0x0, 0x85,
0x10, 0x41, 0xe8, 0x55, 0x0, 0x10, 0x6,
0x30, 0x73, 0xff, 0x0, 0x1, 0x10, 0x0,
0x50, 0x55, 0xb4, 0x38, 0x0, 0x30, 0x0,
0x40, 0x94, 0xdf, 0x36, 0x3, 0x10, 0x0,
// Flute
0x0, 0x45,
0x10, 0x1a, 0xd1, 0x1c, 0x10, 0x31, 0x7,
0x0, 0xb8, 0x73, 0x94, 0x1, 0x30, 0x0,
0x10, 0x98, 0xe0, 0x9c, 0x31, 0x13, 0x7,
0x0, 0xa5, 0x60, 0x4, 0x11, 0x11, 0x80,
// Square Lead (矩形波 )
0x0, 0x85,
0x0, 0x7f, 0xf4, 0xbb, 0x0, 0x10, 0x40,
0x0, 0xaf, 0xa0, 0xe, 0x3, 0x10, 0x40,
0x0, 0x2f, 0xf3, 0x9b, 0x10, 0x21, 0x41,
0x0, 0xaf, 0xa0, 0xe, 0x1, 0x10, 0x40,
// Saw Lead (ノコギリ波)
0x0, 0x85,
0x10, 0x70, 0xf0, 0x68, 0x41, 0x14, 0x7,
0x0, 0x7f, 0xd0, 0x28, 0x41, 0x14, 0x40,
0x10, 0x3f, 0xf0, 0x51, 0x41, 0x14, 0xe7,
0x0, 0x8f, 0xe0, 0x28, 0x41, 0x14, 0x40,
// Tinkle Bell
0x01,0x45, // modify BO:0 -> BO:1
0x30,0x46,0xF5,0x41,0x44,0xE0,0x03,
0x70,0x66,0xCE,0x2E,0x44,0x20,0x00,
0x20,0x26,0xC5,0x78,0x44,0x77,0x08,
0x40,0x55,0xFD,0x04,0x54,0x60,0x00,
// NewAgePd
0x01,0x45, // modify BO:0 -> BO:1
0x31,0x3F,0xF0,0x98,0x44,0x70,0x0D,
0x40,0x47,0xF0,0x2E,0x44,0x50,0x00,
0x00,0x11,0x60,0x62,0x03,0x17,0x0E,
0x00,0x51,0x81,0x02,0x03,0x10,0x00,
// RimShot
0x00,0x45,
0x59,0x50,0xF0,0x14,0x44,0xC0,0x17,
0x79,0x77,0xF7,0x00,0x44,0xB0,0x00,
0x68,0x6A,0xF8,0x00,0x44,0xC0,0x00,
0x78,0x77,0xF7,0x00,0x44,0x70,0x10,
// Castanet
0x01,0x45, // modify BO:0 -> BO:1
0x58,0x97,0xFF,0x08,0x44,0x70,0x0E,
0x59,0xF8,0xAF,0x00,0x44,0x50,0x30,
0x68,0x55,0xF0,0x9C,0x44,0x20,0x28,
0x98,0x9A,0xCA,0x50,0x44,0x50,0x00,
// Footer
0x80,0x03,0x81,0x80};
#define YMF825_GRAND_PIANO 0x00
#define YMF825_BRIGHT_PIANO 0x01
#define YMF825_ELECTRIC_PIANO 0x02
#define YMF825_HARPSICHORD 0x03
#define YMF825_WIBRAPHONE 0x04
#define YMF825_ROCK_ORGAN 0x05
#define YMF825_CHURCH_ORGAN 0x06
#define YMF825_HARMONICA 0x07
#define YMF825_ACOUSTIC_GUITAR 0x08
#define YMF825_FLUTE 0x09
#define YMF825_LEAD_SQUARE 0x0a
#define YMF825_LEAD_SAWTOOTH 0x0b
#define YMF825_TINKLE_BELL 0x0c
#define YMF825_NEWAGE_PD 0x0d
#define YMF825_RIMSHOT 0x0e
#define YMF825_CASTANET 0x0f
uint8_t toneIndex = YMF825_NEWAGE_PD;
uint8_t rimshotIndex = YMF825_RIMSHOT;
int noteFnum[12] = {357,378,401,425,450,477,505,535,567,601,637,674}; // piano
uint8_t busy[16] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
void mosiChar(uint8_t command, uint8_t data)
{
digitalWrite(PIN_CS, LOW);
SPI.transfer(command);
SPI.transfer(data);
digitalWrite(PIN_CS, HIGH);
}
void mosiBurst( unsigned char adrs, unsigned char* data, int count )
{
digitalWrite(PIN_CS, LOW);
SPI.transfer(adrs);
for (int i = 0; i<count; i++) {
SPI.transfer(*(data + i));
}
digitalWrite(PIN_CS, HIGH); // Data mode
}
void init()
{
// Power Rail Selection
// レジスタ#29のbit0で、5V単一電源動作(0)か2電源動作(1)かを設定します。
// この設定はアナログ電源ONの前に実施します。
// (#29)|7|6|5|4|3|2|1| 0 | Reset Value
// 0x1D |0|0|0|0|0|0|0|DRV_SEL| 0x00
mosiChar( 0x1D, 0 );
// Power down control
// アナログ電源制御
// VREF/SPOUT1/SPOUT2/DACの4ブロックに対して個別にパワーON/OFFができますが、
// 最初にVREFのみONにして、各機能ブロックのソフトウェアリセットを済ませる。
// (#02)|7|6|5|4|3|2|1|0| Reset Value
// 0x02 |0|0|0|0| AP3-0 | 0x0F
// The AP0-3 is the power-down control register bits in the analog block.
// When setting a register bit to "1"(reset value), its power-down state is established
// AP0:VREF,IREF/AP1:SPAMP,SPOUT1/AP2:SPAMP,SPOUT2/AP3:DAC
mosiChar( 0x02, 0x0e );
delay(1);
// Controlling the internal master clock
// パワーオン直後はパワーセーブ状態になっていて、内部回路にクロックが供給されていません。
// レジスタ#0のbit0を1にすることで内部回路へのクロック供給が開始されます。
// bit0を1にすることで内部回路へのクロック供給を開始する。
// (#00)|7|6|5|4|3|2|1| 0 | Reset Value
// 0x00 |0|0|0|0|0|0|0|CLKE| 0x00
// To active the clock, set the CLKE to "1" with the ALRST set to "1"
mosiChar( 0x00, 0x01 );
// Reset all the interface register
// bit7を1→0にすれば内部ブロックのリセットが解除され、初期設定は完了です。
// このビットを下げるまでは、レジスタ#0-2,4,29以外へのアクセスは無効です。
// (#01)| 7 |6|5|4|3|2|1|0| Reset Value
// 0x01 |ALRST|0|0|0|0|0|0|0| 0x80
mosiChar( 0x01, 0x00 );
// Soft Reset
// レジスタの詳細は公開されていません
// (#26)|7|6|5|4|3|2|1|0| Reset Value
// 0x1A | SFTRST7-0 | 0x00
mosiChar( 0x1A, 0xa3 );
delay(1);
mosiChar( 0x1A, 0x00 );
delay(30);
mosiChar( 0x02, 0x04 );
delay(1);
mosiChar( 0x02, 0x00 );
// Master Volume
// (#25)| 7|6|5|4|3|2 |1|0| Reset Value
// 0x19 |Master Volume|0|0| 0x00
// mosiChar( 0x19, 0x3C); // 0x3C( +9dB) default
// mosiChar( 0x19, 0xCC); // 0x33( 0dB)
mosiChar( 0x19, 0xcc );
// mosiChar( 0x19, 0x84); // 0x21(-18dB)
// mosiChar( 0x19, 0x60); // 0x18(-27dB)
// mosiChar( 0x19, 0x00); // mute
// Mute, Channle Volume & Master Volume Interpolation
// (#27)|7| 6 | 5 | 4 | 3 | 2 | 1 | 0 | Reset Value
// 0x1B |0|DADJT|MUTE_ITIME|CHVOL_ITIME|MVOL_ITIME| 0x00
mosiChar( 0x1B, 0x3f );
// Control the interpolation in a mute state. This register bit works for all the 16 channels.
// (#20)|7|6|5|4|3|2|1| 0 |
// 0x14 |0|0|0|0|0|0|0|DIR_MT|
mosiChar( 0x14, 0x00 );
// Speaker Amplifier Gain Setting
// (#03)|7|6|5|4|3|2| 1 | 0 | Reset Value
// 0x03 |0|0|0|0|0|0|GAIN1|GAIN0| 0x01
// The GAIN is the register used for selecting a speaker amplifier gain as shown bellow.
// GAIN1 GAIN0 SPAmplifier Gain
// "0" "0" SPOUT gain=5.0dB
// "0" "1" SPOUT gain=6.5dB(reset value)
// "1" "0" SPOUT gain=7.0dB
// "1" "1" SPOUT gain=7.5dB
mosiChar( 0x03, 0x01 );
// Sequencer Volume Setting
// (#09)|7|6|5|4|3 | 2 |1| 0 | Reset Value
// 0x09 |SEQ_Vol4-0|DIR_SV|0|SIZE8| 0x00
mosiChar( 0x09, 0xf8 );
}
void setTone()
{
mosiChar( 0x08, 0xf6 );
mosiChar( 0x08, 0x00 );
mosiBurst( 0x07, tone_data, 485 );
}
void setChannel()
{
mosiChar( 0x0F, 0x30 ); // KeyOn=0/MUTE=1/EG_RST=1
// Channel Volume
// (#16)|7| 6|5|4|3|2 |1| 0 |
// 0x10 |0|Channel Volume|0|DIR_CV|
// DIR_CV="1":No interpolation in the SEQ_VOL and the Chvol
mosiChar( 0x10, 0x71 ); // 0x71=>0d111
// Vibrato modulation
// (#17)|7|6|5|4|3|2|1|0|
// 0x11 |0|0|0|0|0| XVB |
mosiChar( 0x11, 0x00 ); // "0":OFF(reset value)
// This registers specify a multiplier to the generated audio frequency.
// The INT is an integer part and FRAC is a fraction part.
// (#18)|7|6|5|4|3| 2|1|0 |
// 0x12 |0|0|0|INT|FRAC8-6|
// (#19)|7|6|5|4|3|2|1|0|
// 0x13 |0| FRAC5-0 |0|
mosiChar( 0x12, 0x08 ); // INT =1
mosiChar( 0x13, 0x00 ); // FRAC=0
}
void noteOff(uint8_t channel, uint8_t note, uint8_t velocity)
{
int8_t chno = -1;
for(uint8_t i=0; i < 16; i++) {
if (busy[i] == note) {
chno = i;
busy[i] = 0;
break;
}
}
if (chno == -1) return;
mosiChar( 0x0B, chno);
// (#15)|7| 6 | 5 | 4 |3|2|1|0|
// 0x0F |0|KeyOn|Mute|EG_RST|ToneNum|
mosiChar( 0x0F, 0x00); // KeyOn=0:reset/Mute=0:Cancels the mute
}
void noteOn(uint8_t channel, uint8_t note, uint8_t velocity)
{
int8_t chno = -1;
for(uint8_t i=0; i < 16; i++) {
if (busy[i] == note) {
chno = i;
break;
}
}
if (chno == -1) {
for(uint8_t i=0; i < 16; i++) {
if (busy[i] == 0) {
chno = i;
busy[i] = note;
break;
}
}
}
if (chno == -1) return;
int freqNum = noteFnum[note % 12];
uint8_t block = note / 12;
uint8_t freqNumH = ((freqNum>>4)&0x38)|block;
uint8_t freqNumL = 0x7f & freqNum;
// Specifies Channel
// レジスタ#11の下位4ビットに操作したいチャンネル番号を0～15で書き込むことで、
// レジスタ#12～20に対応するチャンネルのControl Registerが現れます。
// (#11)|7|6|5|4|3|2|1|0| Reset Value
// 0x0B |0|0|0|0|channel| 0x00
mosiChar( 0x0B, chno);
// Volume setting for each channel
// (#12)|7|6|5|4|3|2|1|0|
// 0x0C |0| volume |0|0|
mosiChar( 0x0C, velocity & 0x7c);
// Volume setting for each channel
// Frequency number list (Number of cycles)
// | C | C# | D | D# | E | F | F# | G | G# | A | A# | B |
// | 357 | 378 | 401 | 425 | 450 | 477 | 505 | 535 | 567 | 601 | 637 | 674 |
// Octave |-1 |0 |1 |2 |3 |4 |5 |6 |7 |8 |9 |
// Tone |C-B |C-B |C-B |C-B |C-B |C-B |C-B |C-B |C-B |C-B |C-G |
// Note Number |0-11|12-23|24-35|36-47|48-59 |60-71 |72-83 |84-95 |96-107 |108-119|120-127|
// Frequency |8.2-|16.4-|32.7-|65.4-|130.8-|261.6-|523.3-|1046.5-|2093.0-|4186.0-|8372.0-|
// (#13)|7|6| 5 | 4 | 3 | 2 | 1 | 0 |
// 0x0D |0|0|upper 3bits of frequency number |block(Octave)|
mosiChar( 0x0D, freqNumH);
// (#14)|7| 6 | 5 | 4 | 3 | 2 | 1 | 0 |
// 0x0E |0| lower 7bits of frequency number |
mosiChar( 0x0E, freqNumL);
// (#15)|7| 6 | 5 | 4 | 3 | 2 | 1 | 0 |
// 0x0F |0|KeyOn|Mute|EG_RST|Tone Number (Tone Index) |
// The KeyOn is used to control the sound generation '0':KeyOff(reset value)/'1':KeyOn(0x40)
if ((channel & 0x0F)==0x09) {
mosiChar( 0x0F, 0x40|(rimshotIndex&0x0f));
} else {
mosiChar( 0x0F, 0x40|(toneIndex&0x0f));
}
}
void receiveEvent()
{
static unsigned char bufMidi[4];
static unsigned char uch;
static int pos = 0;
static int cmdlen;
if (Serial.available()) {
bufMidi[pos] = Serial.read();
if (pos==0) {
uch = bufMidi[pos] & 0xF0;
switch(uch) {
case 0x90: // Note-on
case 0x80: // Note-off
case 0xB0: // Continuous controller
case 0xE0: // Pitch bend
cmdlen = 3;
break;
case 0xA0: // After-touch
case 0xC0: // Program change
cmdlen = 2;
break;
case 0xD0: // Channel Pressure
cmdlen = 0;
break;
case 0xF0: // System Realtime message (non-musical commands)
cmdlen = 0;
break;
default:
cmdlen = 0;
break;
}
if (cmdlen>0) pos++;
} else {
pos++;
if (pos==cmdlen) {
switch(uch) {
case 0x90:
noteOn(bufMidi[0], bufMidi[1], bufMidi[2]);
break;
case 0x80:
noteOff(bufMidi[0], bufMidi[1], bufMidi[2]);
break;
case 0xB0: // Continuous controller
case 0xE0: // Pitch bend
break;
case 0xA0: // After-touch
break;
case 0xC0: // Program change
toneIndex = bufMidi[1];
break;
}
pos = 0;
} else {
if (pos==4) pos=0;
}
}
}
}
void setup()
{
Serial.begin(115200);
pinMode(PIN_CS, OUTPUT);
digitalWrite(PIN_CS, HIGH);
SPISettings settingsYMF825 = SPISettings(4000000, SPI_MSBFIRST, SPI_MODE0);
SPI.begin(); // SPIを初期化、SCK、MOSI、SSの各ピンの動作は出力、SCK、MOSIはLOW、SSはHIGH
SPI.beginTransaction(settingsYMF825);
init();
setTone();
setChannel();
}
void loop() {
receiveEvent();
}
●プログラム要点
音源LSIのVS1053やSAM2695ではGM音源を実装していますが、YMF825では任意の音色データを登録してチャンネルに割り当てます。
音色は最大16個まで登録可能です。
unsigned char tone_data[485] = {
// Header: 1byte(80H + Maximum Tone Number)
0x8F, // 80H + Tone Number
// GrandPiano
0x01, 0x43
0x00, 0x67, 0xFF, 0x9D, 0x00, 0x10, 0x40,
0x21, 0x33, 0xE2, 0xA3, 0x00, 0x50, 0x00,
0x10, 0x41, 0xD3, 0x88, 0x01, 0x10, 0x00,
0x21, 0x62, 0xD4, 0x02, 0x01, 0x10, 0x00,
// Bright Piano
0x0, 0x43,
0x20, 0x22, 0xf5, 0x9e, 0x0, 0x10, 0x0,
0x20, 0x32, 0xff, 0x72, 0x0, 0x50, 0x0,
0x20, 0x22, 0xfd, 0x66, 0x1, 0x10, 0x0,
0x10, 0x52, 0xf4, 0x28, 0x1, 0x10, 0x0,
～～～～～～～
ここではネット上に公開されていた音色データを収集して16個の音色を登録してあります。
void noteOn(uint8_t channel, uint8_t note, uint8_t velocity)
{
～～～～～～～
if ((channel & 0x0F)==0x09) {
mosiChar( 0x0F, 0x40|(rimshotIndex&0x0f));
} else {
mosiChar( 0x0F, 0x40|(toneIndex&0x0f));
}
}
登録できる音色が最大16個なのでGM音源に比べ遥かに少なくすべての楽器に対応させることはできませんが、
ドラムパートのMIDIチャンネルは10番(0x09)が標準なので、このチャンネルにリムショットを割り当てています。
また、登録した16個の音色から１つ選んで他のチャンネルすべてに適用させています。
ドラム/パーカッションの入力方法 ～準備編～
プログラムの大部分は、他の音源LSIと同様にレジスタに値を書き込んで制御しています。
コード内にコメントを記載しているので、プログラムの理解は容易かと思います。
●ビルド
ソースコードのビルドは、PlatformIO を使っています。
Arduino開発環境構築 PlatformIO
●実行
Raspberry Piのターミナル・ウィンドウでttymidiをバックグランドで起動して、aplaymidi でMIDIデータを再生します
$ ttymidi -s /dev/ttyACM0 -b 115200 &
$ aplaymidi -p 128:1 YoruNiKakeru.mid
YOASOBI - 夜に駆ける
●実際の動作環境
パープルの枠内の統合環境は、ビルド済プログラムをSDカードに保存し、プログラムセレクターにより選択して実行します。
周辺機器を用途に応じて活用できる仕組みになっています。
この統合環境にはTeraTermなどでTELNET接続して制御しています。
Adafruit Qt Py ESP32-S2 には QWIIC(STEMMA QT)コネクタがあり、GPIOピンとして引き出されているI2Cとは別系統になっています。
YMF825側のESP32とシリアル接続にしてもよいのですが、拡張性と利便性の観点からI2Cにしています。
●YAMAHA YMF825 Board と Qt Py ESP32-S2の結線 (SPI接続)
| YMF825Board | - | QT Py ESP32-S2 | - | 統合環境 |
| SS | - | A2 | | |
| MOSI | - | MO | | |
| MISO | | | | |
| SCK | - | SCK | | |
| GND | - | GND | | |
| 5V | - | 5V | | |
| RST_N | | | | |
| Audio Out | | | | |
| 3.3Vin | | | | |
| | | SCL | - | SCL |
| | | SDA | - | SDA |
| | | VIN | - | VIN |
| | | GND | - | GND |
※SPI接続はレベル変換を行っていないので、MOSI(3.3V→5V)のみで、MISO(5V→3.3V)は非接続にします
ttymidiを利用するときは、統合環境のESP32とRaspberry PiをUSB接続しています
●補足：トーンデータ
YAMAHA YMF825 の Tone Paramater 資料と、FM音源の専門書を参考に、自分だけの音を作ってみてはいかがでしょうか。
tone_data = [
0x81, # 80H + Tone Number
0x01, # BO (Basic Octave)
0x43, # LFO,ALG
0x00,0x67,0xFF,0x9D,0x00,0x10,0x40, # Operator1 Setting
0x21,0x33,0xE2,0xA3,0x00,0x50,0x00, # Operator2 Setting
0x10,0x41,0xD3,0x88,0x01,0x10,0x00, # Operator3 Setting
0x21,0x62,0xD4,0x02,0x01,0x10,0x00, # Operator4 Setting
0x80,0x03,0x81,0x80] # Footer
YMF825は8つのアルゴリズムをサポートしています。
アルゴリズムは４つのオペレータと深く絡んでいるので、各オペレータの情報も編集しないとよい音質は得られません。
YMF825には29種類の波形が内蔵されているので、波形を変更するのも面白いかもしれません。
●参考文献
ESP32でYMF825音源のデモ(音色データ、音階、和音)
|
Raspberry Pi（ラズベリー パイ）は、ARMプロセッサを搭載したシングルボードコンピュータ。イギリスのラズベリーパイ財団によって開発されている。
Arduinoで学ぶ組込みシステム入門(第2版)
●Arduinoを使って組込みシステム開発を理解する
・ハードウェアやソフトウェアなどの基礎知識/
・設計から実装までを系統的に説明するモデルベース開発/
・Arduinoを用いた実際の開発例
最新 使える! MATLAB 第3版
◆◆すぐに「使える!」 全ページフルカラー!◆◆
・MATLAB R2022bに対応し、解説もより詳しく!/
・コマンド・スクリプトの例が豊富で、動かして学べる!/
・超基本から解説。これから使いはじめる人にぴったり!/
・全編フルカラー、スクリーンショットも豊富!
Amazon Web Services基礎からのネットワーク＆サーバー構築改訂４版
1.システム構築をインフラから始めるには/
2.ネットワークを構築する/
3.サーバーを構築する/
4.Webサーバーソフトをインストールする/
5.HTTPの動きを確認する/
6.プライベートサブネットを構築する/
7.NATを構築する/
8.DBを用いたブログシステムの構築/
9.TCP/IPによる通信の仕組みを理解する
C言語は第二の母国語: 独学学生時代から企業内IT職人時代に培った、独立のための技術とノウハウ 平田豊著
学生時代から独学でプログラミングをはじめ、企業内でデバイスドライバを開発し、そして独立後もたくさんのアプリケーション開発や技術書制作に携わってきた著者。その筆者が大事に使い続ける「C言語」の“昔と今”について、気づいたことや役立つ知識、使ってきたツールなどについて、これまで記してきたことを整理してまとめました。
本書では、現役プログラマーだけでなく、これからプログラミングを学ぶ学生などにも有益な情報やノウハウを、筆者の経験を元に紹介しています。
1冊ですべて身につくJavaScript入門講座
・最初の一歩が踏み出せる！ 初心者に寄り添うやさしい解説
・最新の技術が身につく！ 今のJavaScriptの書き方・使い方
・絶対に知っておきたい！ アニメーションとイベントの知識
・プログラミングの基本から実装方法まですべて学べる
図解！ Git & GitHubのツボとコツがゼッタイにわかる本
ソフトウェア開発では欠かすことのできないGit、GitHub。
これからGit、GitHubを使いたいという入門者の方でも、実際に手を動かしながら使い方を学べます。
C自作の鉄則！2023 (日経BPパソコンベストムック)
メーカー製のパソコンはスペックが中途半端で、自分が本当に欲しい機種がない――。そう思っている人には、ぜひ自作パソコンをお薦めします。自作パソコンのパーツは進化が速く、しかも驚くほど種類が豊富。価格も性能も、幅広く用意されているため、満足度100％の“自分だけの1台”を手に入れることができます。
Interface 2023年6月号
特集：第1部 フィルタ設計 基礎の基礎/
第2部 係数アプリや波形観測アプリで合点！FIR&IIRフィルタ作り/
第3部 配布プリント基板で体験！マイコンで動くフィルタ作り
日経Linux 2023年5月号
【特集 1】 AI時代の最強フリーソフト ～ 25のやりたいを実現！
【特集 2】 AWS、Azureのうまみを無料で体感！面倒なことはクラウドに任せよう
【特集 3】 新しいRaspberry Pi Cameraで遊んでみよう
【特集 4】 Linuxで旧型PCを復活！ 1kg切るモバイルPCを「ChromeOS Flex」でChromebook化
ラズパイマガジン2022年秋号
特集：5大人気ボード 電子工作超入門
「半導体不足で在庫が不足し、電子工作のボードがなかなか買えない…」。そんな今にふさわしい特集を企画しました。5種の人気ボードにすべて対応した電子工作の入門特集です。「GPIO」や「I2C」を使った電子パーツの制御方法は、どのボードでも同じです。手に入れられたボードを使って、今こそ電子工作を始めましょう。
地方で稼ぐ! ITエンジニアのすすめ
学歴、理系の知識、専門スキル……全部なくてもITエンジニアになれる!
地方でも高収入でやりがいをもって働ける!ITエンジニアの魅力を一挙大公開
Raspberry Piのはじめ方2022
本書は、ラズパイやPicoの買い方やインストール、初期設定といった基本から、サーバー、電子工作、IoT、AIといったラズパイならではの活用方法まで、1冊でお届けします。
ラズパイをこれから始める方向けに、全36ページの入門マンガ「女子高生とラズベリーパイ」も巻末に掲載。これを読むだけでラズパイがどんなものなのか、すぐに分かって触れるようになります。
ハッカーの学校 IoTハッキングの教科書
生活にとけこみ、家電機器を便利にするIoT技術。
Webカメラなど、便利の裏側に潜むセキュリティの危険性をハッキングで検証。
専門家がパケットキャプチャからハードウェアハッキングまで、その攻撃と防御を徹底解説。
本書は2018年7月に刊行された「ハッカーの学校IoTハッキングの教科書」に一部修正を加えた第2版です。
攻撃手法を学んで防御せよ! 押さえておくべきIoTハッキング
本書は、経済産業省から2021年4月にリリースされた、IoTセキュリティを対象とした『機器のサイバーセキュリティ確保のためのセキュリティ検証の手引き』の『別冊2 機器メーカに向けた脅威分析及びセキュリティ検証の解説書』をもとに、IoT機器の開発者や品質保証の担当者が、攻撃者の視点に立ってセキュリティ検証を実践するための手法を、事例とともに詳細に解説しました。
ポチらせる文章術
販売サイト・ネット広告・メルマガ・ブログ・ホームページ・SNS…
全WEB媒体で効果バツグン!
カリスマコピーライターが教える「見てもらう」「買ってもらう」「共感してもらう」すべてに効くネット文章術
プログラマーは世界をどう見ているのか 西村博之著
イーロン・マスク(テスラ)、ジェフ・べゾス(Amazon)、ラリー・ペイジ(Google)…etc.
世界のトップはなぜプログラマーなのか?
ニーア オートマタ PLAY ARTS改 <ヨルハ 二号 B型 DX版> PVC製 塗装済み可動フィギュア
「NieR:Automata」より、ヨルハ二号B型こと2BがPLAY ARTS改に新たに登場!
高級感の感じられるコスチュームや髪の質感、洗練されたボディバランス、細かなデティールに至るまでこだわり抜かれた逸品。
DX版には通常版のラインナップに加え2Bの随行支援ユニット ポッド042などをはじめ“純白の美しい太刀"白の約定やエフェクトパーツ、自爆モードを再現できる換装用ボディパーツ、シーンに合わせて変えられる顔パーツ2種も付属する豪華な仕様に。
作中のあらゆるシーンを再現することが可能なファン必見の一品となっている。
Newtonライト2.0 ベイズ統計
ベイズ統計は,結果から原因を推定する統計学です。AIや医療などの幅広い分野で応用されています。その基礎となるのは18世紀に考えだされた「ベイズの定理」です。
この本では,ベイズ統計学のきほんをやさしく紹介していきます。
白光(HAKKO) ダイヤル式温度制御はんだ吸取器 ハンディタイプ FR301-81
無水エタノールP 500mlx2個パック(掃除)
ケイバ(KEIBA) マイクロニッパー MN-A04
サンハヤト SAD-101 ニューブレッドボード
白光(HAKKO) HEXSOL 巻はんだ 精密プリント基板用 150g FS402-02
[Amazon限定ブランド]【指定第2類医薬品】PHARMA CHOICE 解熱鎮痛薬 解熱鎮痛錠IP 100錠
|
