#include <Adafruit_AHTX0.h>

Adafruit_AHTX0 aht;

//----  DS1302 definition ---------------------
#define PIN_CE    16
#define PIN_IO    15
#define PIN_SCLK 14

const uint8_t Sun = 1;
const uint8_t Mon = 2;
const uint8_t Tue = 3;
const uint8_t Wed = 4;
const uint8_t Thr = 5;
const uint8_t Fri = 6;
const uint8_t Sat = 7;

static char clockTime[13];
static char editTime[20];
static char shortTime[7];

static String  recv = "";
//----------------------------------------

int characterdata[10][7] = {
                                    {1,1,1,1,1,1,0},
                                    {0,1,1,0,0,0,0},
                                    {1,1,0,1,1,0,1},
                                    {1,1,1,1,0,0,1},
                                    {0,1,1,0,0,1,1},
                                    {1,0,1,1,0,1,1},
                                    {1,0,1,1,1,1,1},
                                    {1,1,1,0,0,0,0},
                                    {1,1,1,1,1,1,1},
                                    {1,1,1,1,0,1,1} };
int anode[7] = {4,5,6,13,2,3,7};
int cathode[5] = {12,11,10,9,8};
int digits[4];

// 整数値をBCDに変換
byte dec2bcd(int x) {
  return ((x/10)<<4)+(x%10);
}

uint8_t bcd2dec(const uint8_t bcd) {
	return (10*((bcd&0xF0)>>4)+(bcd&0x0F));
}

uint8_t shiftInEx() {
	uint8_t input_value=0;
	uint8_t bit=0;
	pinMode(PIN_IO,INPUT);
	for (int i=0; i<8; ++i) {
		digitalWrite(PIN_SCLK,HIGH);
		delayMicroseconds(1);
		digitalWrite(PIN_SCLK,LOW);
		delayMicroseconds(1);

		bit = digitalRead(PIN_IO);
		input_value |= (bit<<i); // Bits are read LSB first.
	}
	return input_value;
}

void shiftOutEx(const uint8_t value) {
	bool pinModeFlag = false;
	pinMode(PIN_IO, OUTPUT);
	for (int i=0;i<8;++i) {
		digitalWrite(PIN_IO, (value>>i)&1);
		delayMicroseconds(1);
		digitalWrite(PIN_SCLK,HIGH);
		delayMicroseconds(1);

		if (i==7) {
			if (value==0xBF) pinModeFlag=true; // clock Burst Read
			if ((value>=0x80)&&(value<=0x8D)&&(value%2)) pinModeFlag=true;
		}
		if (pinModeFlag) {
			pinMode(PIN_IO,INPUT);
		} else {
			digitalWrite(PIN_SCLK,LOW);
			delayMicroseconds(1);
		}
	}
}

uint8_t readReg(const uint8_t reg) {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(reg);
	uint8_t dec = bcd2dec(shiftInEx());
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
	return dec;
}

void writeReg(const uint8_t reg, uint8_t value) {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(reg);
	shiftOutEx(value);
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
}

void writeProtect() {
	writeReg(0x8E,0x00);
}

// トリクルチャージ設定（1ダイオード,2kΩ）
void trickleCharge() {
	writeReg(0x90,0xA5);
}

void getDateBurst() {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(0xBF); //clock Burst Read
	uint8_t ss  = bcd2dec(shiftInEx() & 0x7F);
	uint8_t ii  = bcd2dec(shiftInEx());
	uint8_t hh  = bcd2dec(shiftInEx());
	uint8_t dd  = bcd2dec(shiftInEx());
	uint8_t mm  = bcd2dec(shiftInEx());
	uint8_t day = bcd2dec(shiftInEx());
	uint8_t yy  = bcd2dec(shiftInEx());
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
	sprintf(clockTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	sprintf(editTime, "20%02d-%02d-%02d %02d:%02d:%02d",yy,mm,dd,hh,ii,ss);
	sprintf(shortTime,"%02d%02d%02d",yy,mm,dd);
}

// 時刻を設定する
void adjustClock() {
	char updateTime[13];
	int yy=21,mm=01,dd=18,hh=19,ii=31,ss=00,day=Mon;
	sprintf(updateTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	getDateBurst();
	// シリアル通信開始時の、Arduinoオートリセット機能対応
	if (strcmp(updateTime,clockTime)>0) {
		writeProtect();
		digitalWrite(PIN_SCLK,LOW);
		digitalWrite(PIN_CE,HIGH);
		delayMicroseconds(4);
		shiftOutEx(0xBE); //clock Burst Write
		shiftOutEx(dec2bcd(ss));
		shiftOutEx(dec2bcd(ii));
		shiftOutEx(dec2bcd(hh));
		shiftOutEx(dec2bcd(dd));
		shiftOutEx(dec2bcd(mm));
		shiftOutEx(dec2bcd(day));
		shiftOutEx(dec2bcd(yy));
		//shiftOutEx(0x00); // Write protecton register
		digitalWrite(PIN_CE, LOW);
		delayMicroseconds(4);

		trickleCharge();
	}
}

void updateTime() {
	Serial.println("updateTime=" + recv);
	uint8_t yy = (recv[0]-0x30)*10 + (recv[1]-0x30);
	uint8_t mm = (recv[2]-0x30)*10 + (recv[3]-0x30);
	uint8_t dd = (recv[4]-0x30)*10 + (recv[5]-0x30);
	uint8_t hh = (recv[6]-0x30)*10 + (recv[7]-0x30);
	uint8_t ii = (recv[8]-0x30)*10 + (recv[9]-0x30);
	// writeReg(0x80,dec2bcd(ss)); // 秒
	writeReg(0x82,dec2bcd(ii)); // 分
	writeReg(0x84,dec2bcd(hh)); // 時
	writeReg(0x86,dec2bcd(dd)); // 日
	writeReg(0x88,dec2bcd(mm)); // 月
	writeReg(0x8C,dec2bcd(yy)); // 年
}

void getTime() {
	getDateBurst();
	digits[0] = clockTime[6]-0x30;
	digits[1] = clockTime[7]-0x30;
	digits[2] = clockTime[8]-0x30;
	digits[3] = clockTime[9]-0x30;
}

void setTime() {
	while (Serial.available())  {
		char data = Serial.read();
		Serial.print(data);
		if ((data=='\n')||(data=='\r')) {
			if (recv.length()==10) {
				updateTime();
				getDateBurst();
				Serial.println(clockTime);
			}
			recv = "";
		} else {
			recv += data;
		}
	}
}

void setup_DS1302() {
	digitalWrite(PIN_CE, LOW);
	pinMode(PIN_CE, OUTPUT);
	pinMode(PIN_IO, INPUT);
	digitalWrite(PIN_SCLK, LOW);
	pinMode(PIN_SCLK,OUTPUT);
}

void getTemperature() {
	sensors_event_t humidity, temp;
	aht.getEvent(&humidity, &temp);
	int intTemp = (int)(temp.temperature * 100);
	digits[0] = (int)(intTemp/1000); intTemp -= (digits[0]*1000);
	digits[1] = (int)(intTemp/100);  intTemp -= (digits[1]*100);
	digits[2] = (int)(intTemp/10);   intTemp -= (digits[2]*10);
	digits[3] = intTemp;
}

void setup_AHT10() {
	 if (! aht.begin()) {
		Serial.println("Could not find AHT? Check wiring");
		while (1) delay(10);
	}
}

void drawDigit(int pos, int num) {

	for (int i=0;i<5;++i) pinMode(cathode[i], INPUT);

	pinMode(cathode[pos+1], OUTPUT);
	digitalWrite(cathode[pos+1], 0);

	for (int i=0;i<7;++i) digitalWrite(anode[i], characterdata[num][i]);

	delay(2);
}

void drawColon() {

	for (int i=0;i<5;++i) pinMode(cathode[i], INPUT);

	pinMode(cathode[0], OUTPUT);
	digitalWrite(cathode[0], 0);

	for (int i=0;i<7;++i) digitalWrite(anode[i], 0);
	digitalWrite(anode[1], 1);

	delay(2);
}

void setup () { 

	Serial.begin(115200);

	setup_DS1302();
	setup_AHT10();

	for (int i=0;i<7;++i) {
		pinMode(anode[i], OUTPUT);
		digitalWrite(anode[i], LOW);
	}
	for (int i=0;i<5;++i) {
		pinMode(cathode[i], INPUT);
	}
}

void showLED() {
	for(int i=0;i<250;i++) {
		drawDigit(0,digits[0]);
		drawDigit(1,digits[1]);
		drawColon();
		drawDigit(2,digits[2]);
		drawDigit(3,digits[3]);
	}
}

void loop () {
	setTime();
	getTime();
	for(int i=0;i<3;i++) showLED();
	getTemperature();
	showLED();
}