HOME | Raspberry Pi | ビジネス書籍紹介 | 2021-04-18 (Sun) Today's Access : 17 Total : 277435. Since 10 Sep. 2019

 画像処理 第3回リアルタイムクロック
2020.06.28掲載/2020.10.02更新

YouTubeでポイントを説明しています。画像をクリックすると再生できます。

画像処理第2回では、ArduCamカメラモジュールを使って撮影し、画像をSDカードに保存しました。 この際、画像の保存ファイル名に連番を付けていましたが、第3回ではリアルタイムクロックを用いることで、 撮影時刻をファイル名に使えるようにします。

■更新情報
2020.10.02 サンプルのソースコードを修正しました。
本文掲載のDS1302リアルタイムクロックモジュールで使われているDS1302チップでは正常に動作したのですが、 単体で別のDS1302チップを購入して試したところ、時刻情報の取得が正常に行われませんでした。
標準の、shiftIn(), shiftOut()関数を使用せずに、レジスタを操作することで対応しました。 また、バースト転送 getDataBurst() にも対応しました。
修正ソースコードを文末に掲載しています。

■開発環境

パソコンから、TeraTeamでラズパイにSSH接続、ラズパイでビルドしたコードを、Arduino に転送します。
ラズパイのディストリビューションは、Raspbian Stretch、開発環境に platformio を使用しています。
→ Ref.Arduino開発環境構築 PlatformIO

■DS1302リアルタイムクロックモジュール

基板の構成はとてもシンプルで、DS1302リアルタイムクロックICと32.768kHz水晶発振子、CR2032用電池ホルダーで構成されています。

このモジュールをそのまま自作カメラの基板上に配置するのは美的ではないので、分解しちゃいました。


■クリスタル(水晶発振子)32.768kHz
時計などに使用している32.768kHzのクリスタルです。
・負荷容量:12.5pF
・直列抵抗:50kΩmax
・並列容量:0.9pFtyp
・動作温度範囲:-10~+60℃
・許容偏差:±20ppm(±20x10-6)

■CR2032リチウム電池ホルダー
CR2032はプログラムテスト用に使用します。 最終的には、電気二重層コンデンサを用います。

リード線をはんだ付けして、ショートしないように先端にはメスピンヘッダーを取り付けました。


■DS1302 リアルタイムクロックIC
トリクルチャージャ機能
2100年までうるう年を補正
TTL互換(VCC = 5V)
完全動作電圧:2.0V~5.5V
消費電流:300nA以下(2.0V時)
【データシート】 【DS1302概要】

インターフェイスは、CE(Chip Enable),I/O(データ入出力),SCLK(同期用クロック)の3線が使われています。
■配線
Arduino -  DS1302  - CRYSTAL/CR2032
5V - [1]Vcc2 Power-Supply   
   [2]X1  - Crystal 32.768kHz
   [3]X2  - Crystal 32.768kHz
GND - [4]GND  - CR2032(-)
D2 - [5]CE    
D3 - [6]I/O    
D4 - [7]SCLK   
   [8]Vcc1 Battery Backup - CR2032(+)
Arduino側のD2~4は任意に変更可能です。



■テスト用プログラムの作成

$ mkdir RTC
$ cd RTC
$ platformio init -b nanoatmega328

$ vi src/ds1302.ino
#define PIN_CE   2
#define PIN_IO   3
#define PIN_SCLK 4

char clockTime[15]; // 撮影時刻用文字列

void setup() {
	pinMode(PIN_SCLK,OUTPUT);
	pinMode(PIN_CE,  OUTPUT);
	Serial.begin(115200);
	adjustClock();
}

void loop(){
	getDateTime();
	Serial.println(clockTime);
	delay(1000);
}
各種ピンのモード設定、シリアル通信設定を行い、setup()関数内の、adjustClock()で時刻を設定しています。
loop()処理では、1秒間隔でRTCからgetDateTime()関数で時刻を取得して、シリアル出力しています。

プログラムの詳細に移ります。
DS1302のデータシートをもとに説明していきます。


DS1302との時刻の読み書きには上記、レジスタアドレスを指定して、BCD値によるデータの受け渡しを行います。

BCD:二進化十進数
二進化十進数(BCD、Binary-coded decimal)とは、コンピュータにおける数値の表現方式の一つで、十進法の1桁を、0から9までを表す二進法の4桁で表したものです。


データ転送のタイミングは、CE(Chip Enable)をHIGHにすることで行います。

プログラムを起動した際の、DS1302への時刻の設定の部分です。
byte dec2bcd(int x) {
  return ((x/10)<<4)+(x%10);
}

void writeDS1302(int adr, int v) {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE, HIGH);
	shiftOut(PIN_IO, PIN_SCLK, LSBFIRST, adr);
	shiftOut(PIN_IO, PIN_SCLK, LSBFIRST, v);
	digitalWrite(PIN_CE,  LOW);
}

void adjustClock() {
	char checkTime[15];
	int yy=20,mm=6,dd=25,hh=18,ii=35,ss=0;
	sprintf(checkTime,"20%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	getDateTime();
	if (strcmp(checkTime,clockTime)>0) {
		writeDS1302(0x80, dec2bcd(ss));
		writeDS1302(0x82, dec2bcd(ii));
		writeDS1302(0x84, dec2bcd(hh));
		writeDS1302(0x86, dec2bcd(dd));
		writeDS1302(0x88, dec2bcd(mm));
		writeDS1302(0x8C, dec2bcd(yy));
	}
}
Arduinoにはオートリセット機能があり、プログラムを書き込むときやシリアル通信を開始したときにもリセットされます。
リセットされるたびに、時刻設定されると時間が戻ってしまうので、それを防ぎます。
プログラム書き込み時に時間合わせに設定する時刻(checkTime)と、getDateTime()で取得したDS1302側(clockTime)の時刻を比較して、 時刻合わせに使用する時刻のほうが新しい場合のみ、時刻を書き換えるようにしています。

次に、DS1302から時刻を取得する部分です。
int readDS1302(int adr) {
	int bcd;
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,  HIGH);
	shiftOut(PIN_IO, PIN_SCLK, LSBFIRST, adr);
	bcd = shiftIn(PIN_IO, PIN_SCLK, LSBFIRST);
	digitalWrite(PIN_CE, LOW);
	return (bcd&0x0f)+(10*(bcd>>4));
}

void getDateTime(){
	int yy,mm,dd,hh,ii,ss,ck;
	while(1) {
		ss = readDS1302(0x81);
		ii = readDS1302(0x83);
		hh = readDS1302(0x85);
		dd = readDS1302(0x87);
		mm = readDS1302(0x89);
		yy = readDS1302(0x8d);
		ck = readDS1302(0x81);
		if (ck>=ss) break;
	}
	sprintf(clockTime,"20%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
}
while(1)ループ内では、最初に秒を取得して、分、時、日、月、年を取得し、最後に再度、秒の情報を取得しています。 最初と最後で秒が等しいか、最後に取得した秒が最初の秒より大きい場合にループを抜けます。
これは、極短時間での処理なので、ほとんど発生しないとは思いますが、59秒から0秒へ移る際の対応です。
例えば、2020年12月31日23時59分59秒に時刻を取得しようとしたとき、、秒の取得から始めて、年を取得する直前で 1秒進んでしまった場合、2021年に移り、結果は2021年12月31日23時59分59秒となり、1年間の誤差が発生します。
この制御では、59秒から0秒に移った際には、再度、時刻を取得しなおしています。

それでは、Arduino Nano と Raspberry Pi Zero W をUSB接続して実行してみます。
$ platformio run -t upload
$ platformio device list
/dev/ttyUSB0
------------
Hardware ID: USB VID:PID=1A86:7523 LOCATION=1-1
Description: USB Serial

/dev/ttyAMA0
------------
Hardware ID: 20201000.serial
Description: ttyAMA0

$ platformio device monitor -p /dev/ttyUSB0 -b 115200
Looking for advanced Serial Monitor with UI? Check http://bit.ly/pio-advanced-monitor
--- Miniterm on /dev/ttyUSB0 115200,8,N,1 ---
--- Quit: Ctrl+C | Menu: Ctrl+T | Help: Ctrl+T followed by Ctrl+H ---
20200625183514
20200625183515
20200625183516
20200625183517
......

■トリクルチャージ設定
DS1302にはトリクルチャージの機能があります。 トリクルチャージは、二次電池の自然放電を補うために、主電源からの電力供給を受けているときには、微小電流によりバックアップ用電池を充電する機能です。
CR2032電池は充電できないので、この機能を利用するには、充電可能なLIR2032を使用するか、今回実装する電気二重層コンデンサーを用いる方法があります。

電気二重層コンデンサー1F 5.5V
・容量:1F
・耐圧:5.5V
・内部抵抗:30Ω(1kHz)
・外形:Φ21.5mmx9.5mm
・足ピッチ:約5mm
・重量:約7g

電気二重層コンデンサは小型大容量で電圧保持特性に優れています。 メモリや内部時計ICのバックアップ電源として有効です。 適度な内部抵抗を持ち、特別な回路なしで簡単に使えます。 耐圧が5V以上あり、一般的デジタル回路に簡単に使えます。

ボタン電池CR2032を電気二重層コンデンサに交換しました。


データシートをみてみましょう。

初期状態(Initial power-on state)では、RS(BIT0&1)は0で、トリクルチャージ機能は無効になっています。
トリクルチャージする際には、DS1302の内部抵抗とダイオードを選択することができます。

ダイオード1本(電圧降下0.7V)と2KΩの抵抗の組み合わせを選択した場合を考えてみます。
電気二重層コンデンサの容量を大雑把に計算すると
1F × 5V = 5C = 5A・s = 0.00139Ah = 1.39mAh.
になります。
トリクルチャージにより、流れる電流は最大で
Imax = (5.0V ? diode drop) / R1 ? (5.0V ? 0.7V) / 2k? ? 2.2mA
となり、容量1F(1.39mA)の電気二重層コンデンサーであれば、短時間に充電されてしまいます。

電気二重層コンデンサーの有効な容量を1mAとした場合、DS1302の消費電流は300nA以下(2.0V時)なので
1mAh/(300nA*24h)=138.8(日)
主電源をOFFにしていても、二次電池からの電力供給で、RTCは100日程度は動作していると思われます。

トリクルチャージの機能を有効にします。(1 Diode, 2KΩの場合)
void adjustClock() {
	char checkTime[15];
	int yy=20,mm=6,dd=26,hh=20,ii=15,ss=0;
	sprintf(checkTime,"20%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	getDateTime();
	if (strcmp(checkTime,clockTime)>0) {
		writeDS1302(0x80, dec2bcd(ss));
		writeDS1302(0x82, dec2bcd(ii));
		writeDS1302(0x84, dec2bcd(hh));
		writeDS1302(0x86, dec2bcd(dd));
		writeDS1302(0x88, dec2bcd(mm));
		writeDS1302(0x8C, dec2bcd(yy));

		writeDS1302(0x90, 0xA5);
	}
}

これで、写真撮影、画像保存、時刻取得の機能はできました。残っているのは主電源周りになります。

続きは画像処理第4回に掲載します。


2020.10.02 修正ソースコード
#define PIN_CE   2
#define PIN_IO   3
#define PIN_SCLK 4

const uint8_t Sun = 1;
const uint8_t Mon = 2;
const uint8_t Tue = 3;
const uint8_t Wed = 4;
const uint8_t Thr = 5;
const uint8_t Fri = 6;
const uint8_t Sat = 7;

static char clockTime[13]; // 時刻文字列 yymmddhhiiss
static char editTime[20];  // 時刻表示用文字列
static char shortTime[7];  // 撮影用文字列

// 整数値をBCDに変換
byte dec2bcd(int x) {
  return ((x/10)<<4)+(x%10);
}

uint8_t bcd2dec(const uint8_t bcd) {
	return (10*((bcd&0xF0)>>4)+(bcd&0x0F));
}

uint8_t shiftInEx() {
	uint8_t input_value=0;
	uint8_t bit=0;
	pinMode(PIN_IO,INPUT);
	for (int i=0; i<8; ++i) {
		digitalWrite(PIN_SCLK,HIGH);
		delayMicroseconds(1);
		digitalWrite(PIN_SCLK,LOW);
		delayMicroseconds(1);

		bit = digitalRead(PIN_IO);
		input_value |= (bit<<i); // Bits are read LSB first.
	}
	return input_value;
}

void shiftOutEx(const uint8_t value) {
	bool pinModeFlag = false;
	pinMode(PIN_IO, OUTPUT);
	for (int i=0;i<8;++i) {
		digitalWrite(PIN_IO, (value>>i)&1);
		delayMicroseconds(1);
		digitalWrite(PIN_SCLK,HIGH);
		delayMicroseconds(1);

		// We're about to read data -- ensure the pin is back in input mode
		// before the clock is lowered
		if (i==7) {
			if (value==0xBF) pinModeFlag=true; // clock Burst Read
			if ((value>=0x80)&&(value<=0x8D)&&(value%2)) pinModeFlag=true;
		}
		if (pinModeFlag) {
			pinMode(PIN_IO,INPUT);
		} else {
			digitalWrite(PIN_SCLK,LOW);
			delayMicroseconds(1);
		}
	}
}

uint8_t readReg(const uint8_t reg) {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(reg);
	uint8_t dec = bcd2dec(shiftInEx());
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
	return dec;
}

void writeReg(const uint8_t reg, uint8_t value) {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(reg);
	shiftOutEx(value);
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
}

// Initialize a new chip by turning off write protection.
// These method needn't always be called.
void writeProtect() {
	writeReg(0x8E,0x00);
}

// トリクルチャージ設定(1ダイオード,2kΩ)
void trickleCharge() {
	writeReg(0x90,0xA5);
}

void getDateBurst() {
	digitalWrite(PIN_SCLK,LOW);
	digitalWrite(PIN_CE,HIGH);
	delayMicroseconds(4);
	shiftOutEx(0xBF); //clock Burst Read
	uint8_t ss  = bcd2dec(shiftInEx() & 0x7F);
	uint8_t ii  = bcd2dec(shiftInEx());
	uint8_t hh  = bcd2dec(shiftInEx());
	uint8_t dd  = bcd2dec(shiftInEx());
	uint8_t mm  = bcd2dec(shiftInEx());
	uint8_t day = bcd2dec(shiftInEx());
	uint8_t yy  = bcd2dec(shiftInEx());
	digitalWrite(PIN_CE, LOW);
	delayMicroseconds(4);
	sprintf(clockTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	sprintf(editTime, "20%02d-%02d-%02d %02d:%02d:%02d",yy,mm,dd,hh,ii,ss);
	sprintf(shortTime,"%02d%02d%02d",yy,mm,dd);
}

void getDate() {
	uint8_t yy,day,mm,dd,hh,ii,ss,ck;
	while(1) {
		ss  = readReg(0x81);
		ii  = readReg(0x83);
		hh  = readReg(0x85);
		dd  = readReg(0x87);
		mm  = readReg(0x89);
		day = readReg(0x8A);
		yy  = readReg(0x8D);
		ck  = readReg(0x81);
		// 59秒→0秒対策
		if (ck>=ss) break;
	}
	sprintf(clockTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	sprintf(editTime, "20%02d-%02d-%02d %02d:%02d:%02d",yy,mm,dd,hh,ii,ss);
	sprintf(shortTime,"%02d%02d%02d",yy,mm,dd);
}

// 時刻を設定する
void adjustClock() {
	char updateTime[13];
	int yy=20,mm=10,dd=2,hh=8,ii=58,ss=00,day=Fri;
	sprintf(updateTime,"%02d%02d%02d%02d%02d%02d",yy,mm,dd,hh,ii,ss);
	getDateBurst();
	// シリアル通信を開始の、Arduinoオートリセット機能対応
	if (strcmp(updateTime,clockTime)>0) {
		writeProtect();
		digitalWrite(PIN_SCLK,LOW);
		digitalWrite(PIN_CE,HIGH);
		delayMicroseconds(4);
		shiftOutEx(0xBE); //clock Burst Write
		shiftOutEx(dec2bcd(ss));
		shiftOutEx(dec2bcd(ii));
		shiftOutEx(dec2bcd(hh));
		shiftOutEx(dec2bcd(dd));
		shiftOutEx(dec2bcd(mm));
		shiftOutEx(dec2bcd(day));
		shiftOutEx(dec2bcd(yy));
		//shiftOutEx(0x00); // Write protecton register
		digitalWrite(PIN_CE, LOW);
		delayMicroseconds(4);

		trickleCharge();
	}
}

void setup() {

	digitalWrite(PIN_CE, LOW);
	pinMode(PIN_CE, OUTPUT);
	pinMode(PIN_IO, INPUT);
	digitalWrite(PIN_SCLK, LOW);
	pinMode(PIN_SCLK,OUTPUT);

	Serial.begin(115200);

	adjustClock();
}

void loop(){
	//getDateBurst();
	getDate();
	Serial.println(editTime);
	delay(1000);
}

■参考文献
リアルタイムクロック DS1302 をArduinoで動かしてみる
https://github.com/msparks/arduino-ds1302


【深層学習関連】
20.11.21 深層学習 第1回環境整備
20.12.19 深層学習 第2回マルコフ連鎖・自動歌詞生成
21.01.02 深層学習 第3回コード進行解析

【画像処理関連】

20.05.28 画像処理 第1回トイカメラ
20.06.09 画像処理 第2回カメラモジュール制御
20.06.28 画像処理 第3回リアルタイムクロック
20.07.08 画像処理 第4回電源回路
20.10.27 画像処理 第5回自作デジカメ初号機完成
20.11.10 画像処理 第6回ドーナツデジカメ
【音楽関連】

20.01.05 第1回 abcjs 楽譜作成・演奏スクリプト
20.01.09 I2S通信によるハイレゾ音源再生
20.01.18 MIDI再生:FM音源YMF825+Arduino編
20.01.24 FM音源YMF825+micro:bit編
20.02.13 Piano Hat & Rosegarden
20.06.22 波形処理 第1回 音の波と三角関数
20.07.22 波形処理 第2回 平均律と純正律
20.08.26 波形処理 第3回 黒鍵と白鍵
21.01.02 深層学習 第3回 コード進行解析
21.01.16 波形処理 第4回 コード演奏
【WEBサイト構築関連】

19.10.15 第1回 前準備
19.10.20 第2回 Ubuntu Server インストール
19.10.27 第3回 Ubuntu Server 詳細設定
19.10.28 番外編 無線LAN接続設定
19.11.02 第4回 Apache WEBサーバ設定
19.11.05 第5回 PHP 設定
19.11.10 第6回 MySQL 設定
19.11.11 第7回 DNS (bind) 設定
19.11.16 第8回 メールサーバ(Postfix)設定・前編
19.11.21 第9回 メールサーバ(Postfix)設定・後編
19.11.24 第10回 ファイアウォール(iptables) 設定
19.11.25 第11回 crontab 設定
19.12.01 第12回 運用準備
19.12.03 第13回 Windowsパソコンに開発環境を作る
19.12.05 第14回 WEBサーバー公開
19.12.10 第15回 動的サイト制作
19.12.11 第16回 簡単なアクセスカウンターを作る
20.03.04 TTGO-Camera による定点観測・WEB公開
21.03.15 第17回 サーバ・リプレイス
21.03.27 第18回 システム移行
【開発環境関連】

19.12.19 Raspbian Stretch LITE インストール
19.12.19 ファイル共有 dokany + Win-sshfs
19.12.26 Arduino開発環境構築 PlatformIO
20.02.04 電子組版 upLaTeX
21.04.13 GPIO拡張
21.04.14 無線LAN動的切替え
【SNS関連】

20.03.18 テキスト読み上げ gTTS
20.04.24 Twitter-LINE連携によるビジネス活用
20.05.19 テキスト読み上げ AquesTalk pico LSI
21.02.27 TweLite Neural Network 第1回環境設定
【周辺機器関連】

20.01.01 1280x800 HDMI MONITOR
20.01.12 micro:bitをコマンドラインで使う
20.02.04 サーマルプリンタを使う
20.03.27 M5Stackキーボードを利用する
20.06.29 液晶キャラクターディスプレイLCD1602A
20.08.03 Seeeduino XIAO
20.08.09 LGT8F328P - Arduino clone
20.09.18 電流計測モジュール INA219
21.02.09 Raspberry Pi Pico 開発環境構築
21.03.06 疑似コンソール
21.03.20 Raspberry Pi Pico 突入電流制御
21.04.04 Raspberry Pi Pico Explorer Base
【その他】

19.12.13 モバイルバッテリーによる瞬間停電対策
20.04.10 電卓を制御して数字を表示する
20.05.06 箱庭回路 蓄電&昇圧回路
20.09.04 箱庭回路 センサーライト
20.09.29 シガーライターIC s090c
20.10.13 自動給水装置 LM393+NE555
20.12.05 FM放送受信 TEA5767
21.01.30 DVD Player LED
21.02.16 癒しの電子回路

 ニーア オートマタ PLAY ARTS改 <ヨルハ 二号 B型 DX版> PVC製 塗装済み可動フィギュア
「NieR:Automata」より、ヨルハ二号B型こと2BがPLAY ARTS改に新たに登場! 高級感の感じられるコスチュームや髪の質感、洗練されたボディバランス、細かなデティールに至るまでこだわり抜かれた逸品。 DX版には通常版のラインナップに加え2Bの随行支援ユニット ポッド042などをはじめ“純白の美しい太刀"白の約定やエフェクトパーツ、自爆モードを再現できる換装用ボディパーツ、シーンに合わせて変えられる顔パーツ2種も付属する豪華な仕様に。 作中のあらゆるシーンを再現することが可能なファン必見の一品となっている。
Interface 2021年5月号
~ 5G時代のコモンセンス ! 旬の信号処理をパソコンでマスタ ! ~
☆特 集 [ザ・新人研修]Pythonで無線信号処理
☆特 設: ソフトウェア・ラジオで合点 ! 無線通信[変復調]技術
☆新連載: IoT定番プロトコルMQTT: IoTに向く理由

ラズパイマガジン2021年春号
モーターやLED、小型ディスプレイ、スイッチなど、多様な電子パーツ450種を一挙に紹介します。 特性や価格の一覧表を用意したので、用途に合った適切な製品を選べます。
トランジスタ技術 2021年4月号
☆特集~ホビーも実践も軽快・即開発のA-D内蔵ワンチップ~
「AVRでサクッとマイコン開発」
日経Linux 2021年3月号
【特集 1】まる分かり50ステップ Linux 超入門
【特集 2】あなたのワガママかなえます! WindowsのアプリをLinuxで使いたい
【特集 3】公衆Wi-Fiは危険がいっぱい!? パスワードの盗聴を実験してみた
【特集 4】キーボード一体型の新モデル Raspberry Pi 400を検証
【特集 5】ラズパイで楽しむLinuxライフ オンラインのドキュメント編集をNextcloudとCollabora Onlineで実現

15Stepで踏破 自然言語処理アプリケーション開発入門
エンジニアの実務に役立つ知識に絞り、独自に15の学習ステップを体系化しました。 数値計算にNumPy、形態素解析にMeCab、機械学習にscikit-learn、ディープラーニングに Keras等を使い、Pythonのコードを記述し動かしていきます。
プログラミング・ビットコイン ―ゼロからビットコインをプログラムする方法

Linuxサーバーがゼロから作れる本
このLinuxを使いこなす上で一番手っ取り早いのが自分でLinuxサーバーを構築してみることです。 WindowsやMacのパソコンしか使ったことが無い人でも理解できるよう、 しくみや手順の解説を丁寧にまとめ上げた、ゼロからのサーバー入門ガイドです。

Raspberry Pi 3 Model B V1.2 (日本製) 国内正規代理店品
【仕様概要】CPU:ARM 1.2GHz 4コア、GPU:2コア 3D・動画支援、RAM:1GB、ネットワーク:LAN/Wi-Fi/Bluetooth、インターフェース:USB/HDMI/オーディオ/GPIO(UART/I2C/I2S/SPI...)。

Arduino Nano
ATmega328搭載/ 動作電圧: 5V/ 入力電源電圧(推奨):7~12V/ デジタル入出力ピン: 14本/ PWMチャンネル: 6本/ アナログ入力チャンネル: 8本/ 直流電流(1ピン当り最大): 40 mA/ 直流電流(3.3Vピン、1ピン当り最大): 50 mA/ Flashメモリ: 32 KB (ATmega328) 内2KBはブートローダーで使用/ SRAM: 2 KB (ATmega328)/ EEPROM: 1 KB (ATmega328)/ Clock Speed: 16 MHz
逆引き PIC電子工作 やりたいこと事典
機能が豊富で、速度・アナログ制御・省電力性・コストの面でもアドバンテージをもつPICマイコン。そんなPICマイコンの使い方を、目的別にやりたいことから引ける、逆引きタイプのガイドブックです。
C言語による PICプログラミング大全
2002年に初版、2009年に第2版を発売した名著『C言語によるPICプログラミング入門』 が大幅リニューアルし「大全」として生まれ変わりました。 本書では、機能豊富なPIC16F1シリーズを使いこなすために、統合開発環境を MPLAB X IDEに、CコンパイラはMicrochip Technology社純正のXC8に、それぞれ変更しました。 C言語でPICマイコンのプログラミングを始めたい方から、最新のPICマイコンの機能をとことん使い倒したい方まで、必ず役に立つ1冊です。
PICと楽しむRaspberry Pi活用ガイドブック
「PICマイコン+Raspberry Pi3B」という組み合わせで、高機能な電子工作を簡単に実現し、電子工作を各段に高度化する方法について解説していきます。
ESP32&Arduino 電子工作 プログラミング入門
電子工作ファンに人気のマイコンArduino、そしてWiFiとBluetooth内蔵でネットワーク接続しやすいESP32。それらのマイコンでプログラムを組む際に使うのが「Arduino言語」です。
超特急Web接続!ESPマイコン・プログラム全集
IoT技術の回路とプログラムを解説しました. トランジスタ技術2016年9月号と2017年3月号の特集に 最新の情報を加筆して一冊に仕上げました. 回路とプログラムのサンプル資料として最適です. ラズベリー・パイやIchigoJamを連動させた例も紹介しています
M5Stack用カード型キーボードユニット
M5Stackにフル機能のQWERTY配列キーボードを実装できるユニットです。複数のボタンの組み合わせ(Sym + Key、Shift + Key、Fn + Key)や豊富なキーの値を出力することが可能です。
Ubuntu サーバー徹底構築
サーバー用UbuntuでLinuxサーバーを構築しよう! 導入からLinuxやコマンドの基本、各種サーバー構築、バックアップやストレージ管理まで! サーバー用Linuxディストリビューションとして定評のあるUbuntu Serverの中でも、 10年長期サポート版であるUbuntu Server 18.04 LTSに対応!
[改訂第3版]Linuxコマンドポケットリファレンス
本書はLinux操作に必要なコマンドを収録したポケットリファレンスです。機能別にコマンドを分類し、各コマンドページでは書式/使用例などをコンパクトにまとめています。またアルファベット順索引も用意しており、名前しかわからなくてもすぐに目的のコマンドを探すことができます。今回の改訂では仮想化、データベース、クラウド時代に対応したネットワークコマンドなどを追加しています。おもなLinuxディストリビューションのCentOS、Fedora、Debian GNU/Linux、Ubuntuに対応し、初心者から上級者まで必携の1冊です。
できるPRO Apache Webサーバー 改訂版 Version 2.4/2.2/2.0対応
番のApache独学書を改訂しました! CentOS、Ubuntu、Windows、Mac OS Xに対応しています。できるPROシリーズは、実際の画面や詳細なイラスト、概念図などで構成。 はじめての方でも理解しやすくなっています。 インストール、アクセス制限、CGI、モジュール拡張、ログ管理など、基本的なことから実践的なことまでていねいに解説しています。
[改訂第3版]PHPポケットリファレンス
PHPを利用したいすべての方必携の「PHPポケットリファレンス」最新版がついに登場! PHP 5/4による開発の際によく利用される機能を集約し、必要な知識を目的別、逆引きでまとめました。PHP5.3以降を対象とし、PHP4からある機能はPHP4でも利用できることがわかるようになっています。またオブジェクト指向型のAPI解説を大幅に強化。開発の現場には1冊置いておきたい書籍です。
MySQL ポケットリファレンス
MySQLはさまざまなWebサービスの中核を担うデータベースです。本書はMySQLの基礎的な内容を中心に、日常的によく使うちょっとしたコマンドや、外部管理ツールとの連携など、MySQLの管理/運用にあたって便利な情報を素早く探し出すことができます。MySQL自体の操作、MySQL特有のコマンド、MySQL専用管理ツール、PHPからの操作など、MySQLを実際に使っているユーザーに役立つ内容となっています。
Postfix詳解―MTAの理解とメールサーバの構築・運用
電子メールの配送システムの中核を担うプログラム「MTA」(Message Transfer Agent)のひとつが、「Postfix」です。 この全容を記した本です。 すところなく解説していきます。
DNSがよくわかる教科書
本書では、DNSの仕組みから、ドメイン名のルール、主なリソースレコードの内容、コマンドによる動作確認、DNSの運用ノウハウ、DNSSECの基礎知識まで、順を追ってやさしく解説します。

Copyright © 2011-2022 Sarako Tsukiyono All rights reserved®.